prontera,165,60,2	script	见习工匠	73,{
	disable_items;
	mes "[见习工匠]";
	if (Zeny >= 400000) {
		mes "我一直在研究如何强化防具来最大化其性能。";
		next;
		mes "[见习工匠]";
		mes "附魔是一项神奇的技术，能将神秘的状态力量注入防具的隐藏凹槽中。";
		next;
		mes "[见习工匠]";
		mes "但请注意：如果背包中有两件相同装备，附魔会按背包顺序作用于第一件装备。";
		next;
		mes "[见习工匠]";
		mes "这可能导致非目标装备被附魔。为安全起见，请确保只携带^5555ff一件目标防具^000000...";
		next;
		mes "[见习工匠]";
		mes "若因携带多件相同装备导致意外，恕不负责。";
		next;
		switch(select("无洞防具:有洞防具:高阶防具:下次再说")) {
		case 1:
			setarray .@Items[0],2307,2309,2314,2316,2321,2325,2327,2328,2330,2332,2334,2335,2341,2344,2346,2348,2350,2337,2386,2394,2395,2396;
			set .@j,50;
			break;
		case 2:
			setarray .@Items[0],2311,2318,2319,2320,2308,2310,2315,2317,2322,2324,2326,2331,2333,2336,2342,2345,2347,2349,2351;
			set .@j,55;
			set .@k,1;
			break;
		case 3:
			setarray .@Items[0],2364,2365,2391,2374,2375,2376,2377,2378,2379,2380,2381,2382,2387,2388,2389,2390;
			set .@j,60;
			break;
		case 4:
			mes "[见习工匠]";
			mes "有兴趣强化防具时随时再来。";
			close;
		}
		set .@menu$,"";
		for(set .@i,0; .@i<getarraysize(.@Items); set .@i,.@i+1)
			set .@menu$, .@menu$+getitemname(.@Items[.@i])+((.@k)?" [1]":"")+":";
		callsub S_EnchantArmor, .@Items[select(.@menu$)-1], .@j;
		end;
	}
	mes "我是装备附魔师，专门研究防具强化技术。";
	next;
	mes "[见习工匠]";
	mes "如需附魔，请准备^FF000040万Zeny^000000和待强化防具。";
	close;

S_EnchantArmor:
	set .@itemid,getarg(0);
	set .@failrate,getarg(1);
	mes "[见习工匠]";
	if (countitem(.@itemid) == 1) {
		mes "附魔需消耗^FF000040万Zeny^000000，随机附加属性，但有损坏装备的风险。";
		next;
		mes "[见习工匠]";
		mes "^ff5555重要提示：^000000";
		mes "现有精炼等级和卡片将^FF0000全部消失^000000";
		mes "确定要继续吗？";
		next;
		if(select("再考虑一下:开始附魔") == 1) {
			mes "[见习工匠]";
			mes "谨慎是好事，随时欢迎再来。";
			close;
		}
		mes "[见习工匠]";
		mes "很有冒险精神嘛！开始附魔...";
		close2;
		specialeffect2 EF_MAPPILLAR;
		if (Zeny < 400000) {
			mes "[见习工匠]";
			mes "Zeny不足，无法进行附魔。";
			close;
		}
		progressbar "ffff00",7;
		set Zeny, Zeny-400000;
		delitem .@itemid,1;
		switch (rand(1,.@failrate)) {
			case 1: set .@addpart,4702;break;  // STR+3
			case 2: set .@addpart,4712;break;  // AGI+3
			case 3: set .@addpart,4722;break;  // VIT+3
			case 4: set .@addpart,4732;break;  // INT+3
			case 5: set .@addpart,4742;break;  // DEX+3
			case 6: set .@addpart,4752;break;  // LUK+3
			case 7:
			case 8: set .@addpart,4701;break;  // STR+2
			case 9:
			case 10: set .@addpart,4711;break; // AGI+2
			case 11:
			case 12: set .@addpart,4721;break; // VIT+2
			case 13:
			case 14: set .@addpart,4731;break; // INT+2
			case 15:
			case 16: set .@addpart,4741;break; // DEX+2
			case 17:
			case 18: set .@addpart,4751;break; // LUK+2
			case 19:
			case 20:
			case 21: set .@addpart,4700;break; // STR+1
			case 22:
			case 23:
			case 24: set .@addpart,4710;break; // AGI+1
			case 25:
			case 26:
			case 27: set .@addpart,4720;break; // VIT+1
			case 28:
			case 29:
			case 30: set .@addpart,4730;break; // INT+1
			case 31:
			case 32:
			case 33: set .@addpart,4740;break; // DEX+1
			case 34:
			case 35:
			case 36: set .@addpart,4750;break; // LUK+1
			default:
				specialeffect2 EF_PHARMACY_FAIL;
				mes "[见习工匠]";
				mes "非常遗憾...";
				mes "装备在附魔过程中损毁了！";
				close;
		}
		getitem2 .@itemid, 1, 1, 0, 0, 0, 0, 0, .@addpart;
	}
	else {
		mes "未检测到可附魔装备！";
		mes "请确保背包中只有^5555ff一件目标防具^000000。";
		close;
	}
}