pay_d03_i,160,45,3	script	宝石切割匠#ilp20	4_TOWER_17,3,3,{
	mes "[宝石切割匠]";
	mes "你找我有事吗？";
	next;
	switch( select( "你在这里做什么？", "强化装备" ) ) {
	case 1:
		mes "[宝石切割匠]";
		mes "我本来到荒村寻找材料,";
		mes "碰触奇怪光芒后就被传送至此。";
		next;
		mes "[宝石切割匠]";
		mes "暂时决定留在这里,";
		mes "靠近士兵比较安全。";
		mes "想和你谈个交易,";
		mes "需要此地特有材料。";
		next;
		mes "[宝石切割匠]";
		mes "带来材料我可以帮你强化装备,";
		mes "但只能强化特定类型装备。";
		next;
		mes "[宝石切割匠]";
		mes "若有兴趣,我们可以详谈交易细节。";
		close;
	case 2:
		mes "[宝石切割匠]";
		mes "请确保^0000FF装备精炼至少+9^000000,";
		mes "这是强化效果显现的最低要求。";
		next;
		mes "[宝石切割匠]";
		mes "必须^0000FF装备着要强化的物品^000000,";
		mes "否则我无法评估其状态。";
		next;
		mes "[宝石切割匠]";
		mes "强化后装备将脱胎换骨,";
		mes "意味着会^0000FF失去当前精炼等级、卡片与附魔^000000。";
		next;
		mes "[宝石切割匠]";
		mes "我需要^0000FF幻影石和其他材料^000000,";
		mes "选择装备后我会告知所需材料。";
		close2;
		callshop( "barter_ill_moonlight" );
		end;
	}
	end;

OnTouch:
	if (illusion_moonlight > 7)
		npctalk "这到底是什么地方？", "", bc_self;
	end;
}


//========================================================
//= 吸血鬼幻影
//========================================================
gef_dun01,139,228,3	script	大商人#illgef	4_M_HUMERCHANT,{
	mes "[大商人]";
	mes "冒险者,你持有^0000cd幻影石^000000吗？";
	mes "若有^0000cd武器、防具或饰品精炼+9以上^000000,";
	mes "可用幻影石与材料换取更高级装备。";
	next;
	mes "[大商人]";
	mes "那你需要什么？";
	next;
	switch( select( "兑换幻影装备", "幻影石是什么？", "能强化兑换品吗？", "取消" ) ) {
	case 1:
		specialeffect EF_HFLIMOON3;
		emotion ET_BEST;
		mes "[大商人]";
		mes "好好使用它,找到更多幻影石再来找我!*轻笑*";
		close2;
		callshop( "barter_ill_vampire" );
		end;
	case 2:
		mes "[大商人]";
		mes "你问^0000cd幻影石^000000是什么？";
		mes "其实...没人确切知道其本质。";
		next;
		mes "[大商人]";
		mes "我只知它们稀有罕见,";
		mes "仅存于特殊地点,";
		mes "代客户收集这些石头。";
		next;
		mes "[大商人]";
		mes "客户想研究这些石头,";
		mes "他们支付丰厚报酬,";
		next;
		mes "[大商人]";
		mes "所以我提供^0000cd贵重装备置换服务^000000,";
		mes "借此获取利润。";
		next;
		mes "[大商人]";
		mes "带来^0000cd精炼装备与幻影石^000000,";
		mes "以及此地特有材料,我就能^0000cd强化武器、防具或饰品^000000。";
		next;
		mes "[大商人]";
		mes "这是双赢交易,有兴趣就来找我。";
		close;
	case 3:
		mes "[大商人]";
		mes "想强化兑换的装备？真是周全！";
		next;
		mes "[大商人]";
		mes "之前有位冒险者告诉我,";
		mes "普隆德拉的炼金术师";
		mes "可用幻影石强化幻影装备。";
		next;
		mes "[大商人]";
		mes "幻影石真是炙手可热,";
		mes "人人都想探究其奥秘。";
		next;
		mes "[大商人]";
		mes "想强化装备就去市政厅旁的";
		mes "<NAVI>幻影附魔师<INFO>prontera,90,115,000,0,</INFO></NAVI>那儿。";
		close;
	case 4:
		mes "[大商人]";
		mes "找到心仪装备了吗？";
		mes "有需要随时告诉我。";
		close;
	}
	end;
}

//========================================================
//= 冰冻幻影
//========================================================

// 幻影兑换NPC - 用物品换取幻影装备
ice_dun02,153,18,3	script	幻影石研究员	4_M_ALCHE_B,{
	disable_items;
	mes "[幻影石研究员]";
	mes "啊,幻影石真是神秘莫测...";
	next;
	switch( select( "你在此做什么？", "强化装备", "取消" ) ) {
	case 1:
		mes "[幻影石研究员]";
		mes "为研究寻找幻影石而来。";
		next;
		mes "[幻影石研究员]";
		mes "此洞穴充满神秘,";
		mes "但凭我之力难以独自探索。";
		mes "你若进入能帮我收集些材料吗？";
		next;
		mes "[幻影石研究员]";
		mes "作为回报,我会强化你的装备。";
		mes "意下如何？";
		close;
	case 2:
		mes "[幻影石研究员]";
		mes "请确保^4d4dff装备精炼至少+9^000000,";
		mes "且^4d4dff正装备着要强化的物品^000000。";
		next;
		mes "[幻影石研究员]";
		mes "强化后装备会焕然一新,";
		mes "意味着将^4d4dff失去当前精炼与升级等级^000000。";
		next;
		mes "[幻影石研究员]";
		mes "我需要^4d4dff幻影石与其他材料^000000,";
		mes "选定装备后告知所需材料。";
		close2;
		callshop( "barter_ill_frozen" );
		end;
	case 3:
		mes "[幻影石研究员]";
		mes "实在太难获取了..";
		close;
	}
	end;
}


// 幻影强化 - 强化幻影装备
// 注意：成功概率未知
prontera,90,115,5	script	幻影附魔师#0	4_GEFFEN_09,3,3,{
	if (checkweight(1201,1) == 0 || MaxWeight - Weight < 2000) {
		mes "背包超重了,最好先减轻负重。";
		close;
	}
	disable_items;
	if (isbegin_quest(12415) == 0) {
		mes "[幻影附魔师]";
		mes "哦,你持有幻影装备吗？";
		next;
		select("不,我连幻影装备是什么都不知道。");
		mes "[幻影附魔师]";
		mes "抱歉,我应该先自我介绍。";
		next;
		mes "[幻影附魔师]";
		mes "我是专研幻影石的炼金术师,";
		mes "近期冒险者间流传的这种石头。";
		next;
		select("幻影石？");
		mes "[幻影附魔师]";
		mes "你还不知道吧？这可是时下热门。";
		next;
		select("我不关心流行趋势。");
		mes "[幻影附魔师]";
		mes "最近各处涌现奇异之地,";
		mes "幻影石仅存于那些地方,";
		next;
		mes "[幻影附魔师]";
		mes "其原子结构前所未见,*叨叨*...";
		mes "化学链异常...*叨叨*";
		next;
		select("(糟了,他走神了！)");
		mes "[幻影附魔师]";
		mes "总之我能为幻影石兑换的装备附魔,";
		mes "我称之为幻影装备。";
		next;
		select("(这命名真没品味。)");
		mes "[幻影附魔师]";
		mes "这些装备至少与幻影石相性好,";
		mes "存在附魔成功的潜力。";
		next;
		mes "[幻影附魔师]";
		mes "探索幻影世界收集幻影石,";
		mes "兑换装备后我可为你附魔。";
		next;
		mes "[幻影附魔师]";
		mes "这是双赢,我需要幻影石研究,";
		mes "你需要强力装备冒险。";
		next;
		mes "[幻影附魔师]";
		mes "不过服务并非免费,";
		mes "需消耗幻影石和金钱。";
		next;
		mes "[幻影附魔师]";
		mes "若有兴趣,要办理会员服务吗？";
		mes "可享受专属折扣！";
		next;
		if (select( "当然！", "没兴趣。" ) == 2) {
			mes "[幻影附魔师]";
			mes "好吧,改变主意随时找我。";
			close;
		}
		mes "[幻影附魔师]";
		mes "已将你加入会员名单,";
		mes "期待下次见到幻影装备。";
		setquest 12415;
		completequest 12415;
		close;
	}
	mes "[幻影附魔师]";
	mes "我能为幻影装备附魔。";
	next;
	switch( select( "如何收费？", "强化幻影装备属性", "重置幻影装备附魔" ) ) {
	case 1:
		mes "[幻影附魔师]";
		mes "首先说明,只能为特定幻影装备附魔。";
		next;
		mes "[幻影附魔师]";
		mes "最多开启2个附魔槽,";
		mes "每槽消耗5颗幻影石,";
		mes "随时可重置附魔属性。";
		next;
		mes "[幻影附魔师]";
		mes "附魔永不失败,";
		mes "但重置可能失败,现代科学也无法解决。";
		next;
		mes "[幻影附魔师]";
		mes "重置费用按所选成功率浮动,";
		mes "可通过菜单查看具体价格。";
		close;
	case 2:
		.@reset = false;
		break;
	case 3:
		.@reset = true;
		break;
	}
	setarray .@location[0], EQI_HAND_R, EQI_ARMOR, EQI_SHOES, EQI_GARMENT, EQI_ACC_R, EQI_ACC_L, EQI_HEAD_TOP, EQI_HAND_L;
	.@s = select( "右手武器", "盔甲", "靴子", "披风", "右饰品", "左饰品", "头上装备", "左手武器/盾牌" ) - 1;
	.@loc = .@location[.@s];
	.@eq_id = getequipid(.@loc);

	switch(.@eq_id) {
	// 月光幻影
		case 15195:	// 普恩特长袍[幻影]
		case 16063:	// 长柄战锤[幻影]
		case 19209:	// 护士帽[幻影]
		case 20838:	// 围巾[幻影]
		case 19210:	// 苹果弓箭手[幻影]
		case 22133:	// 长靴[幻影]
		case 26007:	// 灵光长矛[幻影]
		case 26109:	// 波尔多法杖[幻影]
		case 28725:	// 月光之剑[幻影]
	// 吸血鬼幻影
		case 28022:	// 渗透者[幻影]
		case 28023:	// 食尸鬼腿甲[幻影]
		case 2039:	// 巫妖之杖[幻影]
		case 18149:	// 攻城强弩[幻影]
		case 28612:	// 启示录[幻影]
		case 20840:	// 古代君主斗篷[幻影]
		case 28508:	// 骷髅戒指[幻影]
		case 28509:	// 魔戒[幻影]
	// 冰冻幻影
		case 1846:	// 格斗拳套[幻影]
		case 13337:	// 飞雪手里剑[幻影]
		case 19223:	// 无边帽[幻影]
		case 28922:	// 神之使者[幻影]
		case 20847:	// 生存斗篷[幻影]
	// 泰迪熊幻影
		case 28745:	// 幻影反击短剑
		case 28244:	// 幻影守门者双剑
		case 2051:	// 幻影幸存者法杖
		case 22190:	// 幻影长靴
		case 19344:	// 幻影热血发带
	// 乌龟幻影
		case 13469:	// 幻影虚无之剑
		case 1326:	// 幻影战斧
		case 32005:	// 幻影战戟
		case 13338:	// 幻影风魔手里剑
		case 16065:	// 幻影钢铁霰弹枪
		case 19247:	// 幻影华丽花朵
	// 双子幻影
		case 450182:	// 疾风铠甲[幻影]
		case 470066:	// 疾风长靴[幻影]
		case 490120:	// 疾风戒指[幻影]
		case 490121:	// 疾风手套[幻影]
		case 550030:	// 荆棘法杖[幻影]
		case 550031:	// 死亡法杖[幻影]
		case 530015:	// 吉勒德拉[幻影]
		case 500030:	// 石中剑[幻影]
		case 620010:	// 毁灭者[幻影]
		case 510034:	// 远古匕首[幻影]
		case 460017:	// 守护者[幻影]
		case 460018:	// 银光守护者[幻影]
	// 卢安达幻影
		case 28626:	// 幻影石板
		case 18174:	// 幻影猎人之弓
		case 19366:	// 幻影哥布灵头盔
		case 15348:	// 幻影哥布灵铠甲
		case 20923:	// 幻影哥布灵肩甲
		case 22192:	// 幻影哥布灵重靴
	// 迷宫幻影
		case 19428:	// 幻影摩菲斯头巾
		case 20948:	// 幻影摩菲斯披肩
		case 32238:	// 幻影摩菲斯戒指
		case 32239:	// 幻影摩菲斯手镯
		case 28254:	// 幻影屠戮者
		case 21050:	// 幻影太极流星镖
		case 32301:	// 幻影黄金权杖
		case 28762:	// 幻影碧色匕首
	// 水下幻影
		case 570008:	// 电吉他[幻影]
		case 580008:	// 电子鳗鱼竿[幻影]
		case 630006:	// 布里欧纳克[幻影]
		case 610012:	// 冰凌拳刃[幻影]
		case 600011:	// 死亡指引者[幻影]
		case 630007:	// 西风之剑[幻影]
		case 450144:	// 圣袍[幻影]
		case 450145:	// 水灵铠甲[幻影]
		case 450146:	// 锁子甲[幻影]
		case 400053:	// 摩立亚头饰[幻影]
		case 480054:	// 摩立亚斗篷[幻影]
		case 490069:	// 摩立亚腰带[幻影]
		case 490070:	// 摩立亚项链[幻影]
			break;
		case -1:
			mes "[幻影附魔师]";
			mes "必须装备所选部位的物品才能附魔。";
			close;
		default:
			mes "[幻影附魔师]";
			mes "这非幻影世界的装备,";
			mes "你竟敢拿它来侮辱我。";
			close;
	}

	for ( .@i = 0; .@i < MAX_ITEM_RDM_OPT-1; ++.@i ) {
		if (getequiprandomoption(.@loc, .@i, ROA_ID) > 0) {
			mes "^ff0000检测到该装备存在随机属性,无法进行附魔。^000000";
			close;
		}
	}

	.@weapon_lvl = getequipweaponlv(.@loc);
	.@loc_enchant = .@loc;	// 强化功能专用变量

	switch(.@weapon_lvl) {
	case 0:
		break;
	case 1:
	case 2:
	case 3:
		if (.@loc_enchant == EQI_HAND_L)
			.@loc_enchant = EQI_HAND_R;	// 左手武器视为右手武器强化
		break;
	default:	// 四级幻影武器不可强化
		mes "[幻影附魔师]";
		mes "这是顶级幻影装备,";
		mes "当今科技无法为其附魔。";
		next;
		mes "[幻影附魔师]";
		mes "除非附魔师愿意赌上身心安康,";
		mes "否则无人能做到。";
		next;
		mes "[幻影附魔师]";
		mes "或许有天你会遇到能驾驭";
		mes "这般神器的匠人。";
		close;
	}

	.@refine = getequiprefinerycnt(.@loc);
	.@card[0] = getequipcardid(.@loc,0);
	.@card[1] = getequipcardid(.@loc,1);
	.@card[2] = getequipcardid(.@loc,2);
	.@card[3] = getequipcardid(.@loc,3);


	switch(.@reset) {
	case false:
		.@item_req = 25271;	// IllusionStone -> 幻影石
		.@item_req_count = 5;

		if (.@card[2] > 0 && .@card[3] > 0) {
			mes "[幻影附魔师]";
			mes "该装备已达最大附魔上限。";
			close;
		}
		if (.@weapon_lvl > 0) {
			mes "[幻影附魔师]";
			mes "想添加何种类型效果？";
			next;
			.@weapon_enchant_type = select( "近战", "远程", "魔法" );
		}
		mes "[幻影附魔师]";
		if (.@card[3] > 0) {
			.@slot = 2;
			.@string$ = "第二";
		}
		else {
			.@slot = 3;
			.@string$ = "第一";
		}
		mes "我将尝试附魔" + .@string$ + "能力槽。";
		mes "^ff0000现有精炼等级和卡片不会损坏,";
		mes "即使失败装备也不会损毁。^000000";
		mes "是否继续？";
		next;
		if (select( "稍后再来", "确定！" ) == 1) {
			mes "[幻影附魔师]";
			mes "没问题,改变主意随时再来。";
			close;
		}
		if (countitem(.@item_req) < .@item_req_count) {
			mes "[幻影附魔师]";
			mes "需要" + .@item_req_count + "颗" + getitemname(.@item_req);
			mes "你的数量不足。";
			close;
		}

		// 反作弊检测
		if (callfunc("F_IsEquipIDHack", .@loc, .@eq_id) || callfunc("F_IsEquipCardHack", .@loc, .@card[0], .@card[1], .@card[2], .@card[3]) || callfunc("F_IsEquipRefineHack", .@loc, .@refine))
			close;

		.@card[.@slot] = callsub( S_Enchant, .@loc_enchant, .@slot, .@weapon_enchant_type );
		delitem .@item_req, .@item_req_count;
		delequip .@loc;
		getitem2 .@eq_id,1,1,.@refine,0,.@card[0],.@card[1],.@card[2],.@card[3];
		mes "[幻影附魔师]";
		mes "附魔完成,请查收。";
		specialeffect2 EF_REPAIRWEAPON;
		close;

	case true:
		if (!F_IsCharm(.@card[2]) || !F_IsCharm(.@card[3])) {
			mes "[幻影附魔师]";
			mes "仅可重置完全附魔的装备,";
			mes "请完成双槽附魔后再来。";
			close;
		}
		mes "[幻影附魔师]";
		mes "重置成功率随付费金额变化,";
		mes "选择你倾向的操作方式？";
		next;
		.@s = select( "稍后再来", "100,000 Zeny (50%)", "200,000 Zeny (60%)", "300,000 Zeny (70%)", "400,000 Zeny (80%)", "500,000 Zeny (90%)" ) - 1;
		if (.@s == 0) {
			mes "[幻影附魔师]";
			mes "没问题,改变主意随时再来。";
			close;
		}
		.@cost = 100000 * .@s;
		.@rate = 40 + 10 * .@s;

		if (Zeny < .@cost) {
			mes "[幻影附魔师]";
			mes "资金不足。";
			close;
		}

		// 反作弊检测
		if (callfunc("F_IsEquipIDHack", .@loc, .@eq_id) || callfunc("F_IsEquipCardHack", .@loc, .@card[0], .@card[1], .@card[2], .@card[3]) || callfunc("F_IsEquipRefineHack", .@loc, .@refine))
			close;

		Zeny -= .@cost;
		delequip .@loc;
		if (rand(100) < .@rate) {
			getitem2 .@eq_id,1,1,.@refine,0,.@card[0],.@card[1],0,0;
			mes "[幻影附魔师]";
			mes "重置完成,请查收。";
			specialeffect2 EF_REPAIRWEAPON;
			close;
		}
		mes "[幻影附魔师]";
		mes "可惜失败了,运气不会永远眷顾你。";
		specialeffect2 EF_LORD;
		close;
	}
	end;

S_Enchant:
	.@slot = getarg(1);
	switch( getarg(0)) {	// 装备位置
	case EQI_HAND_R:
		switch( getarg(2)) {// 武器附魔类型
		case 1:// 近战
			switch( .@slot ) {
			case 2:
			case 3:
				// <物品ID>, <概率> (未知)
				setarray .@item[0],
					4700, 1,	// 力量1
					4701, 1,	// 力量2
					4702, 1,	// 力量3
					4703, 1,	// 力量4
					4720, 1,	// 灵巧1
					4721, 1,	// 灵巧2
					4722, 1,	// 灵巧3
					4723, 1,	// 灵巧4
					4750, 1,	// 幸运1
					4751, 1,	// 幸运2
					4752, 1,	// 幸运3
					4753, 1,	// 幸运4
					4808, 1,	// 斗志4
					4809, 1,	// 斗志3
					4810, 1,	// 斗志2
					4811, 1,	// 斗志1
					4820, 1,	// 斗志5
					29081, 1,	// 期望1级
					29082, 1,	// 期望2级
					29083, 1,	// 期望3级
					29084, 1,	// 期望4级
					29085, 1,	// 期望5级
					29061, 1,	// 野心1级
					29062, 1,	// 野心2级
					29063, 1,	// 野心3级
					29064, 1,	// 野心4级
					29065, 1,	// 野心5级
					4807, 1,	// 攻速1
					4842, 1;	// 攻速2
				break;
			default:
				return 0;
			}
			break;
		case 2:// 远程
			switch( .@slot ) {
			case 2:
			case 3:
				// <物品ID>, <概率>
				setarray .@item[0],
					4730, 1,	// 敏捷1
					4731, 1,	// 敏捷2
					4732, 1,	// 敏捷3
					4733, 1,	// 敏捷4
					4720, 1,	// 灵巧1
					4721, 1,	// 灵巧2
					4722, 1,	// 灵巧3
					4723, 1,	// 灵巧4
					4750, 1,	// 幸运1
					4751, 1,	// 幸运2
					4752, 1,	// 幸运3
					4753, 1,	// 幸运4
					4807, 1,	// 攻速1
					4842, 1,	// 攻速2
					4832, 1,	// 神射手1
					4833, 1,	// 神射手2
					4834, 1,	// 神射手3
					4835, 1,	// 神射手4
					4836, 1,	// 神射手5
					29091, 1,	// 弓弦1级
					29092, 1,	// 弓弦2级
					29093, 1,	// 弓弦3级
					29094, 1,	// 弓弦4级
					29095, 1,	// 弓弦5级
					29071, 1,	// 箭袋1级
					29072, 1,	// 箭袋2级
					29073, 1,	// 箭袋3级
					29074, 1,	// 箭袋4级
					29075, 1;	// 箭袋5级
				break;
			default:
				return 0;
			}
			break;
		case 3:// 魔法
			switch( .@slot ) {
			case 2:
			case 3:
				// <物品ID>, <概率>
				setarray .@item[0],
					4710, 1,	// 智力1
					4711, 1,	// 智力2
					4712, 1,	// 智力3
					4713, 1,	// 智力4
					4720, 1,	// 灵巧1
					4721, 1,	// 灵巧2
					4722, 1,	// 灵巧3
					4723, 1,	// 灵巧4
					4750, 1,	// 幸运1
					4751, 1,	// 幸运2
					4752, 1,	// 幸运3
					4753, 1,	// 幸运4
					4812, 1,	// 咒术4
					4813, 1,	// 咒术3
					4814, 1,	// 咒术2
					4815, 1,	// 咒术1
					4826, 1,	// 咒术5
					4805, 1,	// 治愈量2
					4850, 1;	// 治愈量3
				break;
			default:
				return 0;
			}
			break;
		default:
			return 0;
		}
		break;
	case EQI_ARMOR:
	case EQI_SHOES:
	case EQI_GARMENT:
	case EQI_HAND_L:
	case EQI_HEAD_TOP:
		switch( .@slot ) {
		case 2:
		case 3:
			// <物品ID>, <概率>
			setarray .@item[0],
				4700, 700,	// 力量1
				4701, 600,	// 力量2
				4702, 500,	// 力量3
				4703, 200,	// 力量4
				4740, 700,	// 体力1
				4741, 600,	// 体力2
				4742, 500,	// 体力3
				4743, 200,	// 体力4
				4710, 700,	// 智力1
				4711, 600,	// 智力2
				4712, 500,	// 智力3
				4713, 200,	// 智力4
				4750, 700,	// 幸运1
				4751, 600,	// 幸运2
				4752, 500,	// 幸运3
				4753, 200,	// 幸运4
				4994, 10,	// 力量符文Lv1
				4995, 10,	// 力量符文Lv2
				4997, 10,	// 敏捷符文Lv1
				4998, 10,	// 敏捷符文Lv2
				29009, 10,	// 体力符文Lv1
				29010, 10,	// 体力符文Lv2
				29000, 10,	// 智力符文Lv1
				29001, 10,	// 智力符文Lv2
				29003, 10,	// 灵巧符文Lv1
				29004, 10,	// 灵巧符文Lv2
				29006, 10,	// 幸运符文Lv1
				29007, 10,	// 幸运符文Lv2
				4861, 700,	// 最大HP1
				4862, 600,	// 最大HP2
				4867, 440,	// 最大HP3
				4868, 100,	// 最大HP4
				4992, 10,	// SP吸收1_辅助反应器
				4993, 10,	// HP吸收1_辅助反应器
				29208, 10,	// SP吸收2
				29210, 10;	// HP吸收23
			break;
		default:
			return 0;
		}
		break;
	case EQI_ACC_L:
	case EQI_ACC_R:
		switch( .@slot ) {
		case 2:
		case 3:
			// <物品ID>, <概率>
			setarray .@item[0],
				4700, 576,	// 力量1
				4701, 460,	// 力量2
				4702, 115,	// 力量3
				4703, 11,	// 力量4
				4730, 576,	// 敏捷1
				4731, 460,	// 敏捷2
				4732, 115,	// 敏捷3
				4733, 11,	// 敏捷4
				4740, 576,	// 体力1
				4741, 460,	// 体力2
				4742, 115,	// 体力3
				4743, 11,	// 体力4
				4710, 576,	// 智力1
				4711, 460,	// 智力2
				4712, 115,	// 智力3
				4713, 11,	// 智力4
				4720, 576,	// 灵巧1
				4721, 460,	// 灵巧2
				4722, 115,	// 灵巧3
				4723, 11,	// 灵巧4
				4750, 576,	// 幸运1
				4751, 460,	// 幸运2
				4752, 115,	// 幸运3
				4753, 11,	// 幸运4
				4928, 576,	// SP10
				4870, 460,	// SP25
				4800, 345,	// SP50
				4871, 115,	// SP75
				4801, 11,	// SP100
				4795, 576,	// HP100
				4796, 460,	// HP200
				4797, 345,	// HP300
				4798, 115,	// HP400
				4799, 11;	// HP500
			break;
		default:
			return 0;
		}
		break;
	default:
		return 0;
	}
	.@size = getarraysize(.@item);
	for ( .@i = 0; .@i < .@size; .@i += 2 )
		.@total_rate += .@item[.@i+1];
	.@r = rand(.@total_rate);
	for ( .@i = 0; .@i < .@size; .@i += 2 ) {
		.@rate_tmp += .@item[.@i+1];
		if (.@r < .@rate_tmp)
			break;
	}
	return .@item[.@i];

OnTouch:
	if (isbegin_quest(12415) == 0)
		npctalk "幻影附魔师：对幻影装备有兴趣就来聊聊吧！", "", bc_self;
	end;
}


//============================================================
//= 乌龟幻影
//============================================================

// 兑换NPC
alberta,226,28,3	script	装备研究员	4_TOWER_15,{
	.@illusion_stone_name$ = getitemname(25271);	// 幻影石

	mes "[装备研究员]";
	mes "我研究" + .@illusion_stone_name$ + "强化装备,";
	mes "若提供研究材料可否转交予我？";
	mes "用装备与材料可置换强化装备。";
	next;
	switch( select( "你在此做什么？", "兑换装备" ) ) {
	case 1:
		mes "[装备研究员]";
		mes "研究如何用" + .@illusion_stone_name$ + "强化装备,";
		mes "前往幻影石产地险些无法归来。";
		next;
		mes "[装备研究员]";
		mes "似乎遇见位姑娘...";
		mes "后来找不到返回之路,";
		mes "只得在此向冒险者收集材料,";
		mes "提供强化装备作为交换。";
		close;
	case 2:
		mes "[装备研究员]";
		mes "可兑换装备种类请稍候查看。";
		next;
		mes "[装备研究员]";
		mes "需提供^0000CD精炼+9以上的现有装备^000000,";
		mes "以及^0000CD" + .@illusion_stone_name$ + "等材料^000000。";
		next;
		mes "[装备研究员]";
		mes "兑换后新装备将^0000CD失去精炼等级与附魔^000000,";
		mes "现在选择心仪武器类型？";
		close2;
		callshop( "barter_ill_turtle" );
		end;
	}
}


//============================================================
//= 卢安达幻影
//============================================================

// 兑换NPC
com_d02_i,234,266,6	script	村庄肥皂#Lu	4_M_ORIENT01,{
	mes "[村庄肥皂]";
	mes "为辛勤建设村庄的冒险者提供帮助,";
	mes "可强化你的装备,清单中有需求之物吗？";
	next;
	if (select( "查看幻影装备", "取消" ) == 2) {
		mes "[村庄肥皂]";
		mes "准备好材料随时来找我。";
		close;
	}
	mes "[村庄肥皂]";
	mes "无论出自哪位匠人之手,";
	mes "这些装备定能助你冒险。";
	close2;
	callshop( "barter_ill_luanda" );
	end;
}


//============================================================
//= 水下幻影
//============================================================

iz_d04_i,134,228,4	script	霍伦#霍伦	4_M_BIBI,{
	if (checkweight(1201,3) == 0) {
		mes "物品携带过多无法继续对话,";
		mes "请整理背包后重试。";
		close;
	}
	mes "[霍伦]";
	mes "若持此地稀有材料,";
	mes "可为你强化装备。";
	next;
	mes "[霍伦]";
	mes "是否查看可强化装备？";
	next;
	if (select( "是", "否" ) == 2) {
		mes "[霍伦]";
		mes "有兴趣可随时返回。";
		close;
	}
	mes "[霍伦]";
	mes "种类繁多请仔细挑选,";
	mes "选中即可当场强化。";
	close2;
	callshop( "barter_ill_underwater" );
	end;
}

//============================================================
//= 双子幻影
//============================================================
// ant_d02_i,175,186,3	script	弗罗姆#iltw	MECHANIC,{
ant_d02_i,175,186,3	script	弗罗姆#iltw	HIDDEN_NPC,{
	if (checkweight(1201,3) == 0) {
		mes "- 携带物品过多无法继续任务 -";
		close;
	}
	mes "[弗罗姆]";
	mes "再待下去真要发疯了,";
	mes "全因这诡异氛围。";
	mes "若你多收集些材料,";
	mes "我可帮你强化装备。";
	close2;
	callshop( "barter_ill_twins" );
	end;

OnInit:
	.@npc_id = getnpcid(0);
	setunitdata .@npc_id, UNPC_CLASS, 4058;
	setunitdata .@npc_id, UNPC_SEX, SEX_MALE;
	setunitdata .@npc_id, UNPC_CLOTHCOLOR, 1;
	setunitdata .@npc_id, UNPC_HAIRSTYLE, 11;
	setunitdata .@npc_id, UNPC_HAIRCOLOR, 6;
	end;
}

//============================================================
//= 幻影商人
//============================================================
-	marketshop	market_resonance_stone	-1,100003:2000000:99999,100004:2000000:99999
prontera,88,113,5	script	幻影商人#0829	HIDDEN_NPC,{
	mes "[幻影商人]";
	mes "出售自制随机属性卷轴,";
	mes "可选择两种支付方式。";
	next;
	switch( select( "用金币购买", "用幻影石购买" )) {
		case 1:
			mes "[幻影商人]";
			mes "愿你满意而归。";
			close2;
			callshop "market_resonance_stone";
			end;
		case 2:
			mes "[幻影商人]";
			mes "愿你满意而归。";
			close2;
			callshop "resonance_stone_barter";
			end;
	}
OnInit:
	.@npc_id = getnpcid(0);
	setunitdata .@npc_id,UNPC_CLASS, JOB_MAGE_HIGH;
	setunitdata .@npc_id,UNPC_SEX,SEX_FEMALE;
	setunitdata .@npc_id,UNPC_HEADTOP,142;
	setunitdata .@npc_id,UNPC_HEADMIDDLE,92;
	setunitdata .@npc_id,UNPC_HAIRSTYLE,2;
	setunitdata .@npc_id,UNPC_HAIRCOLOR,2;

	// 补货
	npcshopupdate "market_resonance_stone",100003,2000000,99999;
	npcshopupdate "market_resonance_stone",100004,2000000,99999;
	end;
}



//============================================================
//= 泰迪熊幻影
//============================================================

ein_d02_i,177,158,3	script	渴求幻影石的熊#ITB	4_NASARIAN,{
	.@item_name$ = getitemname(25271); // 幻影石
	mes "[渴求" + .@item_name$ + "的熊]";
	mes "给我" + .@item_name$ + "就给你好处！";
	next;
	switch( select( "在此缘由", "好处[幻影装备]", "离开" ) ) {
	case 1:
		mes "[渴求" + .@item_name$ + "的熊]";
		mes "不知为何在此！";
		mes "其他泰迪熊在排队,";
		mes "我就跟着排了！";
		mes "完全不知会来这里！";
		next;
		mes "[渴求" + .@item_name$ + "的熊]";
		mes "持有" + .@item_name$ + "的熊更强壮！";
		mes "我没有" + .@item_name$ + "！";
		mes "所以比较弱小...";
		next;
		mes "[渴求" + .@item_name$ + "的熊]";
		mes "虽不知" + .@item_name$ + "是何物,";
		mes "但就是想要！";
		close;
	case 2:
		mes "[渴求" + .@item_name$ + "的熊]";
		mes "让现有装备变得更强！";
		next;
		mes "[渴求" + .@item_name$ + "的熊]";
		mes "需^ff0000精炼+9以上装备^000000,";
		mes "原有属性^ff0000会完全消失^000000！";
		next;
		mes "[渴求" + .@item_name$ + "的熊]";
		mes "^ff0000" + .@item_name$ + "^000000最关键！";
		mes "但也需要其他材料,";
		mes "想要好东西总要付出代价。";
		next;
		close2;
		callshop( "barter_ill_teddy" );
		end;
	case 3:
		mes "[渴求" + .@item_name$ + "的熊]";
		mes "好吧...";
		close;
	}
	end;
}